; EVO: A framework for modeling evolution
; by Jon Pearce

patches-own [  ]
turtles-own [
   age
   fitness
   asexual?
]
globals [
   ;le           ; life expectancy
   generation    ; # of current generation
   ;offspring    ; # of offspring produced
   proximity     ; how close do mates need to be
]

;=================== Initializing the Model ===================================

to init-model
   ca
   init-globals
   init-patches
   init-turtles
end

to init-globals
   set life-expectancy 100
   set generation 1
   random-seed new-seed
   set proximity 10
end

to init-patches
   ask patches [init-patch]
end

to init-turtles
   crt init-population
   ask turtles [init-turtle]
end

to init-patch

end

to init-turtle
   setxy random-xcor random-ycor
   set fitness random 100
   set age random life-expectancy
   set color scale-color green fitness 0 100
   set asexual? false
end

;==================== Updating the Model ==================================

to update-model
   if finished?
   [ 
      print "Simulation halted"
      stop 
   ]
   tick
   update-globals
   update-patches
   update-turtles
end

to update-globals
   if 0 = ticks mod life-expectancy [set generation generation + 1]
end

to update-patches
   ask patches [update-patch]
end

to update-turtles
   ask turtles [update-turtle]
end

to-report finished?
   report not any? turtles
end

to update-patch
   
end

to update-turtle
   ifelse age < life-expectancy 
   [
     set age age + 1
     if fitness = 0 [die stop]
     move
     update-fitness
   ] 
   [
     if threshold <= fitness [reproduce]
     die
   ]
   
end

to move
   rt random 360
   fd random 1
end

to update-fitness
   let competitor one-of other turtles with [distance myself < proximity]
   if competitor != nobody [
      let my-score random fitness
      let competitor-score random ([fitness] of competitor)
      let reward 1
      ifelse my-score < competitor-score
      [
         set fitness max (list 0 (fitness - reward))
         ask competitor [set fitness fitness + reward]
      ]
      [
         set fitness fitness + reward
         ask competitor [set fitness max (list 0 (fitness - reward))]
      ]
   ]
end

to reproduce
   ifelse asexual? [
      reproduce-asexually
   ]
   [
      reproduce-sexually
   ]
end

to reproduce-sexually
   let fit-turtles turtles with [threshold <= fitness and distance myself <= proximity]
   let spouse one-of other fit-turtles
   if spouse != nobody
   [
      move-to spouse
      hatch offspring 
      [
         set fitness ([fitness] of myself + [fitness] of spouse) / 2
         set color scale-color green fitness 0 100
         setxy random-xcor random-ycor
      
      ]
      ask spouse [die]
   ]
   die
end

to reproduce-asexually
   hatch offspring 
   [
      set fitness [fitness] of myself
      set color scale-color green fitness 0 100
      setxy random-xcor random-ycor
   ]
end

to-report avg-fitness
   report sum ([fitness] of turtles) / count turtles
end

@#$#@#$#@
GRAPHICS-WINDOW
124
22
563
482
16
16
13.0
1
10
1
1
1
0
1
1
1
-16
16
-16
16
0
0
1
ticks

CC-WINDOW
5
496
951
591
Command Center
0

BUTTON
18
34
93
68
init
init-model
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
17
80
94
113
update
update-model
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
17
140
100
193
generation
generation
5
1
13

MONITOR
18
215
99
268
population
count turtles
17
1
13

MONITOR
17
298
100
351
avg fitness
avg-fitness
2
1
13

SLIDER
593
37
765
70
init-population
init-population
0
500
100
10
1
NIL
HORIZONTAL

SLIDER
593
86
765
119
threshold
threshold
0
100
75
5
1
NIL
HORIZONTAL

SLIDER
595
142
767
175
offspring
offspring
0
10
2
1
1
NIL
HORIZONTAL

SLIDER
594
196
766
229
life-expectancy
life-expectancy
0
100
100
1
1
NIL
HORIZONTAL

TEXTBOX
792
82
942
114
minimum fitness needed to reporduce
13
0.0
1

TEXTBOX
792
137
942
169
number of offspring produced by mating
13
0.0
1

@#$#@#$#@
WHAT IS IT?
-----------
Evo is a framework for modeling evolution.

HOW IT WORKS
------------
The model is controlled by five globals:

|   init-population = initial population size 
|   life-expectancy = # ticks until a turtle mates, if fit, and dies.
|   generation = # of current generation = # of generations so far
|   threshold = minimum fitness needed to reproduce
|   offspring = # of offspring produced by single mating

In addition, each turtle has a fitness attribute, which is initially set to a random integer between 0 and 100, an age, which is intially a random number between 0 and life-expectancy, and a flag, asexual?, which is intially false and determines if the turtle reproduces asexually or not.

The turtles are repeatedly updated. If the age of the turtle is less that  its life expectancy, then the turtle updates its fitness. For example, the update-fitneess procedure might set the fitness of the turtle to a random integer between 0 and 100:

|   to update-fitness
|      set fitness random 100
|   end

In a customization of the framework, this procedure would be redfeined to do something more interesting.

If the turtle has reached the end of its life, if the turtle's fitness is less than the fitness threshold, it dies. If the turtle's fitness is greater than or equal to the fitness threshold, then the turtle reproduces.

In sexual reproduction the turtle chooses a mate from among the other nearby turtles with fitness greater than or equal to the fitness threshold. The number of offspring produced by the coupling is controlled by the offspring global. Each offspring is endowed with a fitness equal to the average of the fitness of each parent. After mating, both parents die.

In asexual reproduction, the reproducing turtle is replaced by an offspring with the same fitness.

HOW TO USE IT
-------------
Pressing the init button initializes the model.

Pressing the update button starts, pauses, or resumes updating the model.

The init-population, threshold, offspring, and life-expectency sliders allow the user to vary the values of the corresponding global variables (described above).

The generation monitor shows the number of the current generation. This is also the number of generations that have existed. This number is the number of ticks divided by the life expectancy, le.

The populatin monitor shows the number of turtles.

The avg fitness monitor shows the average fitness of all turtles.


THINGS TO NOTICE
----------------
All turtles are green. The shade of green reflects its fitness. More fit turtles are a a lighter shade of green. Less fit turtles are a darker shade of green.

The rate of growth of the population (increasing, stable, decreasing) depends on all of the slider variables.

The average fitness increases, as Darwin predicted.


THINGS TO TRY
-------------
Try modifying some of the initial values of the globals.


EXTENDING THE MODEL
-------------------

The model is extended by redefining the update-fitness procedure. For example:

|   to update-fitness
|      let competitor one-of other turtles with [distance myself < proximity]
|      if competitor != nobody [
|         let my-score random fitness
|         let competitor-score random ([fitness] of competitor)
|         let reward 1
|         ifelse my-score < competitor-score
|         [
|            set fitness max (list 0 (fitness - reward))
|            ask competitor [set fitness fitness + reward]
|         ]
|         [
|            set fitness fitness + reward
|            ask competitor [set fitness max (list 0 (fitness - reward))]
|         ]
|      ]
|   end

In this test the turtle selects a random nearby competitor. Each turtle produces a random score less than his or her fitness. The fitness of the turtle with the higher score is incremented by a bonus amount. The loser's fitness is decremented by this amount. 

PROJECT: GENETIC PROGRAMMING
---------------

In genetic programming each turtle is supplied with a description attribute. A description is a length N list of traits. A trait is a number between 0 and max-trait.

The sexual-reproduction procedure spawns a new turtle from a description generated from the parent's descriptions by recombination and mutation. In recombination a random integer 0 <= M < N is chosen. The new description consists of the first M traits of the father's description prepended to the last N - M traits of the mother's description. In mutation another random integer 0 <= K < N is chosen, and the trait at position K is incremented by 1 mod max-traits. 

In the update-fitness procedure, the traits of turtle t are used to determine the turtle's score.

PROJECT: LEARNING AND EVOLUTION
---------------

In this model we equate fitness with knowledge. We suppose each turtle has an inherited capacity to learn, icl, and an inherited capacity to teach, ict. Initially fitness (knowledge) is a random integer between 0 and 100, icl is a random float between 0 and 1, and ict is a random float between -1 and 1.

Instead of competing with other turtles in the update-fitness procedure, a turtle learns from other turtles. When turtle t1 learns from turtle t2, t1's fitness is incremented by icl1 * f2 * ict2 where icl1 is t1's inherited capacity to learn, f2 is t2's fitness, and ict2 is t2's inherited capacity to teach. Also, t2's fitness is decremented by a fixed cost if ict2 > 0 and incremented by this cost if ict2 < 0. In other words, there is a cost to taking time out to teach t1 new tricks and a possible advantage if t2 gains an edge over t1 by passing on bad information.

The offspring of a fit turtle have initial fitness 0 and icl and ict that are equal to the average of the parent's icl and ict values respectively (if reproducing sexually) or the icl and ict of the single parent if reproducing asexually.

Plot the change in the mean value of icl and ict.

What happens when smart turtles are near other smart turtles and dumb turtles are near other dumb turtles?

PROJECT: EVOGOD
----------------

Evogod is a model developed by James Dow to model the evolution of societies that communicate two types of information: real and unreal. For example, real information might be information about the environment that increases the fitness of agents. Unreal information might be supernatural information that decreases the fitness of agents. See http://jasss.soc.surrey.ac.uk/11/2/2.html for the complete paper.

In the NetLogo version of this model turtles have both inherited propensities to communicate real and unreal information (ipr and ipu) and learned propensities to communicate real and unreal information (cpr and cpu).

The update-fitness procedure has two phases. In the learn-real-info phase turtle t1 selects a number of teachers. Teacher t2 increases t1's fitness by an amount proportional to cpr1, t1's propensity to communicate real information. Also, cpr1 is incremented by an amount proportional to ipr1, T1's inherited propensity to communicate real information. 

In the learn-unreal-info phase turtle t1 again selects a number of teachers. Teacher t2 decreases t1's fitness by an amount proportional to cpu1, t1's propensity to communicate unreal information. Also, cpu1 is incremented by an amount proportional to ipu1, T1's inherited propensity to communicate unreal information. 

Reproduction is asexual. The offspring receives the ipr and ipu of the parent. cpr and cpu are reset to some initial value.

The mean values of ipr and ipu are plotted.

NETLOGO FEATURES
----------------

See Sample Models/Biology/Evolution

RELATED MODELS
--------------


CREDITS AND REFERENCES
----------------------
Created by Jon Pearce (http://www.cs.sjsu.edu/faculty/pearce/pearce.html)
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@