options {
    OUTPUT_DIRECTORY="src";
    DEBUG_PARSER=false;
}

PARSER_BEGIN(SuperCalculator)
import java.io.*;

public class SuperCalculator 
{
    public static void main(String[] args) 
    {
        Reader sr = new InputStreamReader(System.in);
        SuperCalculator calc = new SuperCalculator(sr);

        try {
            for (;;) {
                System.out.print("\nExpression? ");
                
                double value = calc.calculate();
                System.out.println("= " + value);
            }
        }
        catch (Exception ex) {
            ex.printStackTrace();
        }
    }
}
PARSER_END(SuperCalculator)

SKIP : {
   <IGNORE : [" ", "\t"]>
}

TOKEN : {
    <NUMBER : <INTEGER> | <REAL1> | <REAL2> | <REAL3>>
  
  | <PLUS     : "+">
  | <MINUS    : "-">
  | <MULTIPLY : "*">
  | <DIVIDE   : "/">
  | <POWER    : "^">
  | <EQ       : "==">
  | <NE       : "!=">
  | <LT       : "<">
  | <LE       : "<=">
  | <GT       : ">">
  | <GE       : ">=">
  | <AND      : "&&">
  | <OR       : "||">
  | <NOT      : "!">
  | <LPAREN   : "(">
  | <RPAREN   : ")">
  | <EOL      : "\n">
    
  | <#INTEGER : (<DIGIT>)+>
  | <#REAL1 : (<DIGIT>)+ "." (<DIGIT>)+>
  | <#REAL2 : (<DIGIT>)+ <E> (<SIGN>)? (<DIGIT>)+>
  | <#REAL3 : (<DIGIT>)+ "." (<DIGIT>)+ <E> (<SIGN>)? (<DIGIT>)+>
  | <#DIGIT : ["0"-"9"]>
  | <#SIGN  : ["+","-"]>
  | <#E     : ["e","E"]>
}

double calculate() throws NumberFormatException : { double v; }
{
  v = expression()
  <EOL> { return v; }
} 

double expression() throws NumberFormatException : { double v, value; }
{
  value = simpleExpr()
  (
      <EQ> v = simpleExpr() { value = value == v ? 1 : 0; }
    | <NE> v = simpleExpr() { value = value != v ? 1 : 0; }
    | <LT> v = simpleExpr() { value = value <  v ? 1 : 0; }
    | <LE> v = simpleExpr() { value = value <= v ? 1 : 0; }
    | <GT> v = simpleExpr() { value = value >  v ? 1 : 0; }
    | <GE> v = simpleExpr() { value = value >= v ? 1 : 0; }
  )?
  { return value; }
} 

double simpleExpr() throws NumberFormatException : { double v, value; }
{
  value = term()
  (
      <PLUS>  v = term() { value += v; }
    | <MINUS> v = term() { value -= v; }
    | <OR>    v = term() { value = (value != 0) || (v != 0) ? 1 : 0; }
  )*
  { return value; }
}

double term() throws NumberFormatException : { double v, value; }
{
  value = power()
  (
      <MULTIPLY> v = power() { value *= v; }
    | <DIVIDE>   v = power() { value /= v; }
    | <AND>      v = power() { value = (value != 0) && (v != 0) ? 1 : 0; }
  )*
  { return value; }
}

double power() throws NumberFormatException : { double v, value; }
{
  value = factor()
  (
    <POWER> v = factor() { value = Math.pow(value, v); }
  )*
  { return value; }
}

double factor() throws NumberFormatException : { double value; }
{
             value = primary()             { return value; }
  | <MINUS>  value = factor()              { return -value; }
  | <NOT>    value = factor()              { return value != 0 ? 0 : 1; }
  | <LPAREN> value = expression() <RPAREN> { return value; }
}

double primary() throws NumberFormatException : { Token t; }
{
  t = <NUMBER> { return Double.parseDouble(t.image); }
}