options {
    OUTPUT_DIRECTORY="src";
    DEBUG_PARSER=false;
}

PARSER_BEGIN(SimpleCalculator)
import java.io.*;

public class SimpleCalculator 
{
    public static void main(String[] args) 
    {
        Reader sr = new InputStreamReader(System.in);
        SimpleCalculator calc = new SimpleCalculator(sr);

        try {
            for (;;) {
                System.out.print("\nExpression? ");
                
                double value = calc.calculate();
                System.out.println("= " + value);
            }
        }
        catch (Exception ex) {
            ex.printStackTrace();
        }
    }
}
PARSER_END(SimpleCalculator)

SKIP : {
   <IGNORE : [" ", "\t"]>
}

TOKEN : {
    <NUMBER : (<DIGIT>)+>
  
  | <PLUS    : "+">
  | <MINUS   : "-">
  | <MULTIPLY: "*">
  | <DIVIDE  : "/">
  | <LPAREN  : "(">
  | <RPAREN  : ")">
  | <EOL     : "\n">
    
  | <#DIGIT : ["0"-"9"]>
}

double calculate() throws NumberFormatException : { double v; }
{
  v = expression()
  <EOL> { return v; }
} 

double expression() throws NumberFormatException : { double v; }
{
  v = simpleExpr() { return v; }
} 

double simpleExpr() throws NumberFormatException : { double v, value; }
{
  value = term()
  (
    <PLUS>  v = term() { value += v; }
  | <MINUS> v = term() { value -= v; }
  )*
  { return value; }
}

double term() throws NumberFormatException : { double v, value; }
{
  value = factor()
  (
    <MULTIPLY> v = factor() { value *= v; }
  | <DIVIDE>   v = factor() { value /= v; }
  )*
  { return value; }
}

double factor() throws NumberFormatException : { double value; }
{
           value = primary()             { return value; }
| <MINUS>  value = factor()              { return -value; }
| <LPAREN> value = expression() <RPAREN> { return value; }
}

double primary() throws NumberFormatException : { Token t; }
{
  t = <NUMBER> { return Double.parseDouble(t.image); }
}