JOB  POWERS OF 2 VERSION 2
     *
     * PRINT THE POWERS OF 2 UP TO 130 DIGITS. COMPUTE THE
     * NUMBERS INSIDE THE PRINT AREA (LOCATIONS 201-332).
     * START WITH THE WORD MARK OVER THE LEAST SIGNIFICANT DIGIT
     * AND MOVE IT LEFT ONE DIGIT EACH TIME AFTER AN OVERFLOW
     * AND PREPEND A '1' AS THE NEW MOST SIGNIFICANT DIGIT.
     * PRINT EACH NUMBER WITHOUT LEADING ZEROES.
     *
               ORG  87        INDEX REGISTER X1 (LOCATIONS 87-89)
     X1        DSA  332       X1 = 332
     *
               ORG  334       LOCATE AFTER THE PRINT AREA + 1
     START     CS   332       CLEAR STORAGE 332 - 300
               CS             CLEAR STORAGE 299 - 200
     *
     MOVEWM    MZ   @0@,1&X1  CLEAR OVERFLOW BITS OF MOST SIG. DIGIT
               CW   1&X1      CLEAR OLD WORD MARK
               MCW  @1@,0&X1  APPEND '1' TO THE BEGINNING OF THE NUMBER
               SBR  X1        X1 = X1 - 1
               C    X1,@201@  IF X1 == 201
               BE   DONE      THEN ALL DONE
               SW   1&X1      ELSE SET NEW WORD MARK ONE LOC. TO THE LEFT
     *
     LOOP      W              WRITE THE NUMBER TO THE PRINTER
               A    333       ADD THE NUMBER TO ITSELF
               BAV  MOVEWM    IF OVERFLOW FLAG SET THEN GO TO MOVEWM
               B    LOOP      ELSE GO TO LOOP
     *
     DONE      H
               END  START